@echo off
REM
REM This is version 0.0.0.5
REM Copyright 2005 Berkeley Data Systems. All rights reserved.
REM

set PATH=%SystemRoot%\system32;%PATH%
setlocal
set DESTINATION=%HOMEDRIVE%\mozy_support

echo Preparing to gather support information
if NOT EXIST %DESTINATION%. goto create_dest
rmdir /s /q %DESTINATION%

:create_dest
mkdir %DESTINATION%
mkdir %DESTINATION%\cab

echo Saving Volume Shadow Copy information
set VSSLOG=%DESTINATION%\cab\vss.log
sc start vss > %VSSLOG%
vssadmin list providers >> %VSSLOG%
vssadmin list writers >> %VSSLOG%
vssadmin list shadows >> %VSSLOG%

echo Saving event logs
cscript %SystemRoot%\system32\eventquery.vbs /fo csv /v /l Application > %DESTINATION%\cab\application_log.csv
cscript %SystemRoot%\system32\eventquery.vbs /fo csv /v /l System > %DESTINATION%\cab\system_log.csv

echo Finding installed drivers, dlls, and services
driverquery /fo csv /v > %DESTINATION%\cab\drivers.csv
sc query state= all > %DESTINATION%\cab\services.csv
reg export "HKCR\CLSID" %DESTINATION%\cab\dlls.reg
reg export "HKLM\System\Setup" %DESTINATION%\cab\setup.reg

echo Finding disk volumes
echo list volume | diskpart > %DESTINATION%\cab\volumes.txt

echo Compressing data
REM prepare to build the CAB file
set DEFFILE=%DESTINATION%\cab\mozy_support.def
echo .OPTION EXPLICIT > %DEFFILE%
echo .Set CabinetNameTemplate=mozy_support.cab >> %DEFFILE%
echo .Set DiskDirectoryTemplate=.\cab >> %DEFFILE%
echo .Set CompressionType=MSZIP >> %DEFFILE%
echo .Set Cabinet=on >> %DEFFILE%
echo .Set Compress=on >> %DEFFILE%
echo mozy_support.def >> %DEFFILE%
echo vss.log >> %DEFFILE%
echo application_log.csv >> %DEFFILE%
echo system_log.csv >> %DEFFILE%
echo drivers.csv >> %DEFFILE%
echo services.csv >> %DEFFILE%
echo dlls.reg >> %DEFFILE%
echo setup.reg >> %DEFFILE%
echo volumes.txt >> %DEFFILE%

REM build the CAB file
pushd %DESTINATION%\cab
makecab /F mozy_support.def
xcopy /y cab\mozy_support.cab ..
popd

REM cleanup
rmdir /q /s %DESTINATION%\cab

start %DESTINATION%
echo Done
endlocal